home *** CD-ROM | disk | FTP | other *** search
/ Gigarom 1 / Gigarom Macintosh Archives (Quantum Leap)(CDRM1080320)(1993).iso / FILES / APP / M-R / PSpice.cpt / NOM.Lib < prev    next >
Text File  |  1990-09-13  |  38KB  |  1,047 lines
  1. * Sample master library of standard devices
  2. *
  3. * Copyright 1990 by MicroSim Corporation
  4. * This is a reduced version of the master library for MicroSim's standard 
  5. * parts libraries. Some components from each type of component library have
  6. * been included here.
  7. *   You are welcome to make as many copies of it as you find convenient.
  8. *
  9. * Release date: July 1990
  10. *
  11. * It takes time for PSpice to scan a library file.  When possible, PSpice
  12. * creates an index file, called <filename>.IND, to speed up the search process.
  13. * The index file is re-created whenever PSpice senses that it might be invalid.
  14.  
  15. *     The following is a summary of parts in this library:
  16. *
  17. *           Part name           Part type
  18. *           ---------           ---------
  19. *           Q2N2222A            NPN bipolar transistor
  20. *           Q2N2907A            PNP bipolar transistor
  21. *           Q2N3904             NPN bipolar transistor
  22. *           Q2N3906             PNP bipolar transistor
  23. *
  24. *           D1N750              zener diode
  25. *           MV2201              voltage variable capacitance diode
  26. *           D1N4148             switching diode
  27. *           MBD101              switching diode
  28. *
  29. *           J2N3819             N-channel Junction field effect transistor
  30. *           J2N4393             N-channel Junction field effect transistor
  31. *
  32. *           LM324               linear operational amplifier
  33. *           UA741               linear operational amplifier
  34. *           LM111               voltage comparator
  35. *
  36. *           K3019PL_3C8         ferroxcube pot magnetic core
  37. *           KRM8PL_3C8          ferroxcube pot magnetic core
  38. *           K502T300_3C8        ferroxcube pot magnetic core
  39. *
  40. *           IRF150              N-type power MOS field effect transistor
  41. *           IRF9140             P-type power MOS field effect transistor
  42. *
  43. *           7402                TTL digital 2-input NOR gate
  44. *           7404                TTL digital inverter
  45. *           7474                TTL digital D-type flip-flop
  46. *           74393               TTL digital 4-bit binary counter
  47. *
  48. *           A4N25               optocoupler
  49. *
  50. *           2N1595              silicon controlled rectifier
  51. *           2N5444              Triac
  52. *
  53. *-------------------------------------------------------------------------------
  54. * Library of bipolar transistor model parameters
  55. *
  56. * This is a reduced version of MicroSim's bipolar transistor model library.
  57. *   You are welcome to make as many copies of it as you find convenient.
  58. *
  59. * The parameters in this model library were derived from the data sheets for
  60. * each part.  Each part was characterize using the Parts option.
  61. * Devices can also be characterized without Parts as follows:
  62. *
  63. *    NE, NC        Normally set to 4
  64. *    BF, ISE, IKF    These are adjusted to give the nominal beta vs.
  65. *            collector current curve.  BF controls the mid-
  66. *            range beta.  ISE/IS controls the low-current
  67. *            roll-off.  IKF controls the high-current rolloff.
  68. *    ISC        Set to ISE.
  69. *    IS, RB, RE, RC    These are adjusted to give the nominal VBE vs.
  70. *            IC and VCE vs. IC curves in saturation.  IS
  71. *            controls the low-current value of VBE.  RB+RE
  72. *            controls the rise of VBE with IC.  RE+RC controls
  73. *            the rise of VCE with IC.  RC is normally set to 0.
  74. *    VAF        Using the voltages specified on the data sheet
  75. *            VAF is set to give the nominal output impedance
  76. *            (RO on the .OP printout) on the data sheet.
  77. *    CJC, CJE    Using the voltages specified on the data sheet
  78. *            CJC and CJE are set to give the nominal input
  79. *            and output capacitances (CPI and CMU on the .OP
  80. *            printout; Cibo and Cobo on the data sheet).
  81. *    TF        Using the voltages and currents specified on the
  82. *            data sheet for FT, TF is adjusted to produce the
  83. *            nominal value of FT on the .OP printout.
  84. *    TR        Using the rise and fall time circuits on the
  85. *            data sheet, TR (and if necessary TF) are adjusted
  86. *            to give a transient analysis which shows the
  87. *            nominal values of the turn-on delay, rise time,
  88. *            storage time, and fall time.
  89. *    KF, AF        These parameters are only set if the data sheet has
  90. *            a spec for noise.  Then, AF is set to 1 and KF
  91. *            is set to produce a total noise at the collector
  92. *            which is greater than the generator noise at the
  93. *            collector by the rated number of decibels.
  94. *
  95. *
  96. .model Q2N2222A NPN(Is=14.34f Xti=3 Eg=1.11 Vaf=74.03 Bf=255.9 Ne=1.307
  97. +        Ise=14.34f Ikf=.2847 Xtb=1.5 Br=6.092 Nc=2 Isc=0 Ikr=0 Rc=1
  98. +        Cjc=7.306p Mjc=.3416 Vjc=.75 Fc=.5 Cje=22.01p Mje=.377 Vje=.75
  99. +        Tr=46.91n Tf=411.1p Itf=.6 Vtf=1.7 Xtf=3 Rb=10)
  100. *        National    pid=19        case=TO18
  101. *        88-09-07 bam    creation
  102.  
  103. .model Q2N2907A PNP(Is=650.6E-18 Xti=3 Eg=1.11 Vaf=115.7 Bf=231.7 Ne=1.829
  104. +        Ise=54.81f Ikf=1.079 Xtb=1.5 Br=3.563 Nc=2 Isc=0 Ikr=0 Rc=.715
  105. +        Cjc=14.76p Mjc=.5383 Vjc=.75 Fc=.5 Cje=19.82p Mje=.3357 Vje=.75
  106. +        Tr=111.3n Tf=603.7p Itf=.65 Vtf=5 Xtf=1.7 Rb=10)
  107. *        National    pid=63        case=TO18
  108. *        88-09-09 bam    creation
  109.  
  110. .model Q2N3904    NPN(Is=6.734f Xti=3 Eg=1.11 Vaf=74.03 Bf=416.4 Ne=1.259
  111. +        Ise=6.734f Ikf=66.78m Xtb=1.5 Br=.7371 Nc=2 Isc=0 Ikr=0 Rc=1
  112. +        Cjc=3.638p Mjc=.3085 Vjc=.75 Fc=.5 Cje=4.493p Mje=.2593 Vje=.75
  113. +        Tr=239.5n Tf=301.2p Itf=.4 Vtf=4 Xtf=2 Rb=10)
  114. *        National    pid=23        case=TO92
  115. *        88-09-08 bam    creation
  116.  
  117. .model Q2N3906    PNP(Is=1.41f Xti=3 Eg=1.11 Vaf=18.7 Bf=180.7 Ne=1.5 Ise=0
  118. +        Ikf=80m Xtb=1.5 Br=4.977 Nc=2 Isc=0 Ikr=0 Rc=2.5 Cjc=9.728p
  119. +        Mjc=.5776 Vjc=.75 Fc=.5 Cje=8.063p Mje=.3677 Vje=.75 Tr=33.42n
  120. +        Tf=179.3p Itf=.4 Vtf=4 Xtf=6 Rb=10)
  121. *        National    pid=66        case=TO92
  122. *        88-09-09 bam    creation
  123.  
  124. *-------------------------------------------------------------------------------
  125. * Library of diode model parameters
  126. *
  127. * Copyright 1990 by MicroSim Corporation
  128. * This is a reduced version of MicroSim's diode model library.
  129. *   You are welcome to make as many copies of it as you find convenient.
  130. *
  131. * The parameters in this model library were derived from the data sheets for
  132. * each part.  Most parts were characterize using the Parts option.
  133. * Devices can also be characterized without Parts as follows:
  134. *    IS        nominal leakage current
  135. *    RS        for zener diodes: nominal small-signal impedance
  136. *            at specified operating current
  137. *    IB        for zener diodes: set to nominal leakage current
  138. *    IBV        for zener diodes: at specified operating current
  139. *            IBV is adjusted to give the rated zener voltage
  140. *
  141. *
  142. *** Zener Diodes ***
  143. *
  144. * "A" suffix zeners have the same parameters (e.g., 1N750A has the same
  145. * parameters as 1N750)
  146. *
  147.  
  148. .model D1N750    D(Is=880.5E-18 Rs=.25 Ikf=0 N=1 Xti=3 Eg=1.11 Cjo=175p M=.5516
  149. +        Vj=.75 Fc=.5 Isr=1.859n Nr=2 Bv=4.7 Ibv=20.245m Nbv=1.6989
  150. +        Ibvl=1.9556m Nbvl=14.976 Tbv1=-21.277u)
  151. *        Motorola    pid=1N750    case=DO-35
  152. *        89-9-18 gjg
  153. *        Vz = 4.7 @ 20mA, Zz = 300 @ 1mA, Zz = 12.5 @ 5mA, Zz =2.6  @ 20mA
  154.  
  155. *** Voltage-variable capacitance diodes
  156.  
  157. * The parameters in this model library were derived from the data sheets for
  158. * each part.  Each part was characterize using the Parts option.
  159. *
  160. .model MV2201   D(Is=1.365p Rs=1 Ikf=0 N=1 Xti=3 Eg=1.11 Cjo=14.93p M=.4261
  161. +        Vj=.75 Fc=.5 Isr=16.02p Nr=2 Bv=25 Ibv=10u)
  162. *        Motorola    pid=MV2201    case=182-03
  163. *        88-09-22 bam    creation
  164.  
  165. *** Switching Diodes ***
  166.  
  167. .model D1N4148    D(Is=0.1p Rs=16 CJO=2p Tt=12n Bv=100 Ibv=0.1p)
  168. *        85-??-??    Original library
  169.  
  170. .model MBD101   D(Is=192.1p Rs=.1 Ikf=0 N=1 Xti=3 Eg=1.11 Cjo=893.8f M=98.29m
  171. +        Vj=.75 Fc=.5 Isr=16.91n Nr=2 Bv=5 Ibv=10u)
  172. *        Motorola    pid=MBD101    case=182-03
  173. *        88-09-22 bam    creation
  174.  
  175. *-------------------------------------------------------------------------------
  176. * Library of junction field-effect transistor (JFET) model parameters
  177.  
  178. * This is a reduced version of MicroSim's JFET model library.
  179. *   You are welcome to make as many copies of it as you find convenient.
  180.  
  181. * The parameters in this model library were derived from the data sheets for
  182. * each part.  Each part was characterize using the Parts option.
  183.  
  184. .model J2N3819    NJF(Beta=1.304m Betatce=-.5 Rd=1 Rs=1 Lambda=2.25m Vto=-3
  185. +        Vtotc=-2.5m Is=33.57f Isr=322.4f N=1 Nr=2 Xti=3 Alpha=311.7
  186. +        Vk=243.6 Cgd=1.6p M=.3622 Pb=1 Fc=.5 Cgs=2.414p Kf=9.882E-18
  187. +        Af=1)
  188. *        National    pid=50        case=TO92
  189. *        88-08-01 rmn    BVmin=25
  190.  
  191. .model J2N4393    NJF(Beta=9.109m Betatce=-.5 Rd=1 Rs=1 Lambda=6m Vto=-1.422
  192. +        Vtotc=-2.5m Is=205.2f Isr=1.988p N=1 Nr=2 Xti=3 Alpha=20.98u
  193. +        Vk=123.7 Cgd=4.57p M=.4069 Pb=1 Fc=.5 Cgs=4.06p Kf=123E-18
  194. +        Af=1)
  195. *        National    pid=51        case=TO18
  196. *        88-07-13 bam    BVmin=40
  197.  
  198. *-------------------------------------------------------------------------------
  199. * Library of linear IC definitions
  200.  
  201. * This is a reduced version of MicroSim's linear subcircuit library.
  202. *   You are welcome to make as many copies of it as you find convenient.
  203. *
  204. * The parameters in the opamp library were derived from the data sheets for
  205. * each part.  The macromodel used is similar to the one described in:
  206. *
  207. *    Macromodeling of Integrated Circuit Operational Amplifiers
  208. *      by Graeme Boyle, Barry Cohn, Donald Pederson, and James Solomon
  209. *    IEEE Journal of SoliE-State Circuits, Vol. SC-9, no. 6,    Dec. 1974
  210. *
  211. * Differences from the reference (above) occur in the output limiting stage
  212. * which was modified to reduce internally generated currents associated with
  213. * output voltage limiting, as well as short-circuit current limiting.
  214. *
  215. * The opamps are modelled at room temperature and do not track changes with
  216. * temperature.  This library file contains models for nominal, not worst case,
  217. * devices.
  218. *
  219. *-----------------------------------------------------------------------------
  220. * connections:   non-inverting input
  221. *                | inverting input
  222. *                | | positive power supply
  223. *                | | | negative power supply
  224. *                | | | | output
  225. *                | | | | |
  226. .subckt LM324    1 2 3 4 5
  227. *
  228.   c1   11 12 2.887E-12
  229.   c2    6  7 30.00E-12
  230.   dc    5 53 dx
  231.   de   54  5 dx
  232.   dlp  90 91 dx
  233.   dln  92 90 dx
  234.   dp    4  3 dx
  235.   egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5
  236.   fb    7 99 poly(5) vb vc ve vlp vln 0 21.22E6 -20E6 20E6 20E6 -20E6
  237.   ga    6  0 11 12 188.5E-6
  238.   gcm   0  6 10 99 59.61E-9
  239.   iee   3 10 dc 15.09E-6
  240.   hlim 90  0 vlim 1K
  241.   q1   11  2 13 qx
  242.   q2   12  1 14 qx
  243.   r2    6  9 100.0E3
  244.   rc1   4 11 5.305E3
  245.   rc2   4 12 5.305E3
  246.   re1  13 10 1.845E3
  247.   re2  14 10 1.845E3
  248.   ree  10 99 13.25E6
  249.   ro1   8  5 50
  250.   ro2   7 99 25
  251.   rp    3  4 9.082E3
  252.   vb    9  0 dc 0
  253.   vc    3 53 dc 1.500
  254.   ve   54  4 dc 0
  255.   vlim  7  8 dc 0
  256.   vlp  91  0 dc 40
  257.   vln   0 92 dc 40
  258. .model dx D(Is=800.0E-18 Rs=1)
  259. .model qx PNP(Is=800.0E-18 Bf=166.7)
  260. .ends
  261. *-----------------------------------------------------------------------------
  262. * connections:   non-inverting input
  263. *                | inverting input
  264. *                | | positive power supply
  265. *                | | | negative power supply
  266. *                | | | | output
  267. *                | | | | |
  268. .subckt uA741    1 2 3 4 5
  269. *
  270.   c1   11 12 8.661E-12
  271.   c2    6  7 30.00E-12
  272.   dc    5 53 dx
  273.   de   54  5 dx
  274.   dlp  90 91 dx
  275.   dln  92 90 dx
  276.   dp    4  3 dx
  277.   egnd 99  0 poly(2) (3,0) (4,0) 0 .5 .5
  278.   fb    7 99 poly(5) vb vc ve vlp vln 0 10.61E6 -10E6 10E6 10E6 -10E6
  279.   ga    6  0 11 12 188.5E-6
  280.   gcm   0  6 10 99 5.961E-9
  281.   iee  10  4 dc 15.16E-6
  282.   hlim 90  0 vlim 1K
  283.   q1   11  2 13 qx
  284.   q2   12  1 14 qx
  285.   r2    6  9 100.0E3
  286.   rc1   3 11 5.305E3
  287.   rc2   3 12 5.305E3
  288.   re1  13 10 1.836E3
  289.   re2  14 10 1.836E3
  290.   ree  10 99 13.19E6
  291.   ro1   8  5 50
  292.   ro2   7 99 100
  293.   rp    3  4 18.16E3
  294.   vb    9  0 dc 0
  295.   vc    3 53 dc 1
  296.   ve   54  4 dc 1
  297.   vlim  7  8 dc 0
  298.   vlp  91  0 dc 40
  299.   vln   0 92 dc 40
  300. .model dx D(Is=800.0E-18 Rs=1)
  301. .model qx NPN(Is=800.0E-18 Bf=93.75)
  302. .ends
  303. *-----------------------------------------------------------------------------
  304.  
  305. *** Voltage comparators
  306.  
  307. * The parameters in this comparator library were derived from data sheets for
  308. * each parts.  The macromodel used was developed by MicroSim Corporation, and
  309. * is produced by the "Parts" option to PSpice.
  310. *
  311. * Although we do not use it, another comparator macro model is described in:
  312. *
  313. *    An Integrated-Circuit Comparator Macromodel
  314. *      by Ian Getreu, Andreas Hadiwidjaja, and Johan Brinch
  315. *    IEEE Journal of Solid-State Circuits, Vol. SC-11, no. 6, Dec. 1976
  316. *
  317. * This reference covers the considerations that go into duplicating the
  318. * behavior of voltage comparators.
  319. *
  320. * The comparators are modelled at room temperature.  The macro model does not
  321. * track changes with temperature.  This library file contains models for
  322. * nominal, not worst case, devices.
  323. *
  324. *-----------------------------------------------------------------------------
  325. * connections:   non-inverting input
  326. *                | inverting input
  327. *                | | positive power supply
  328. *                | | | negative power supply
  329. *                | | | | open collector output
  330. *                | | | | | output ground
  331. *                | | | | | |
  332. .subckt LM111    1 2 3 4 5 6
  333. *
  334.   f1    9  3 v1 1
  335.   iee   3  7 dc 100.0E-6
  336.   vi1  21  1 dc .45
  337.   vi2  22  2 dc .45
  338.   q1    9 21  7 qin
  339.   q2    8 22  7 qin
  340.   q3    9  8  4 qmo
  341.   q4    8  8  4 qmi
  342. .model qin PNP(Is=800.0E-18 Bf=833.3)
  343. .model qmi NPN(Is=800.0E-18 Bf=1002)
  344. .model qmo NPN(Is=800.0E-18 Bf=1000 Cjc=1E-15 Tr=118.8E-9)
  345.   e1   10  6  9  4  1
  346.   v1   10 11 dc 0
  347.   q5    5 11  6 qoc
  348. .model qoc NPN(Is=800.0E-18 Bf=34.49E3 Cjc=1E-15 Tf=364.6E-12 Tr=79.34E-9)
  349.   dp    4  3 dx
  350.   rp    3  4 6.122E3
  351. .model dx  D(Is=800.0E-18 Rs=1)
  352. *
  353. .ends
  354.  
  355. *-------------------------------------------------------------------------------
  356. * Library of magnetic core model parameters
  357.  
  358. * This is a reduced version of MicroSim's magnetic core library.
  359. *   You are welcome to make as many copies of it as you find convenient.
  360.  
  361. * The parameters in this model library were derived from the data sheets for
  362. * each core.  The Jiles-Atherton magnetics model is described in:
  363. *
  364. *   Theory of Ferromagnetic Hysteresis, by D C Jiles and D L Atherton,
  365. *   Journal of Magnetism and Magnetic Materials, vol 61 (1986) pp 48-60
  366. *
  367. * Model parameters for ferrite material (Ferroxcube 3C8) were obtained by
  368. * trial simulations, using the B-H curves from the manufacturer's catalog.
  369. * Then, the library was compiled from the data sheets for each core geometry.
  370. * Notice that only the geometric values change once a material is
  371. * characterized.
  372.  
  373. * Example use:  K2 L2 .99 K1409PL_3C8
  374.  
  375. * Notes:
  376. *   1) Using a K device (formerly only for mutual coupling) with a model
  377. *   reference changes the meaning of the L device: the inductance value
  378. *   becomes the number of turns for the winding.
  379. *   2) K devices can "get away" with specifying only one inductor, as in the
  380. *   example above, to simulate power inductors.
  381.  
  382. * Example circuit file:
  383.  
  384. *+-----------------------------------------------------------------------------
  385. *|Demonstration of power inductor B-H curve
  386. *|
  387. *|* To view results with Probe (B-H curve):
  388. *|* 1) Add Trace for B(K1)
  389. *|* 2) set X-axis variable to H(K1)
  390. *|*
  391. *|* Probe x-axis unit is Oersted
  392. *|* Probe y-axis unit is Gauss
  393. *|*
  394. *|.tran .1 4
  395. *|igen0 0 1 sin(0 .1amp 1Hz 0)    ; Generator: starts with 0.1 amp sinewave, then
  396. *|igen1 0 1 sin(0 .1amp 1Hz 1)    ;   +0.1 amps, starting at 1 second
  397. *|igen2 0 1 sin(0 .2amp 1Hz 2)    ;   +0.2 amps, starting at 2 seconds
  398. *|igen3 0 1 sin(0 .8amp 1Hz 3)    ;   +0.4 amps, starting at 3 seconds
  399. *|RL 1 0 1ohm            ; generator source resistance
  400. *|L1 1 0 20            ; inductor with 20 turns
  401. *|K1 L1 .9999 K528T500_3C8    ; Ferroxcube torroid core
  402. *|.model K528T500_3C8    Core(MS=420E3 ALPHA=2E-5 A=26 K=18 C=1.05
  403. *|+            AREA=1.17 PATH=8.49)
  404. *|.options itl5=0
  405. *|.probe
  406. *|.end
  407. *+-----------------------------------------------------------------------------
  408.  
  409. *** Ferroxcube pot cores: 3C8 material
  410.  
  411. .model K3019PL_3C8    Core(Ms=420E3 Alpha=2E-5 A=26 K=18 C=1.05
  412. +            Area=1.38 Path=4.52)
  413.  
  414. *** Ferroxcube square cores: 3C8 material
  415.  
  416. .model KRM8PL_3C8    Core(Ms=420E3 Alpha=2E-5 A=26 K=18 C=1.05
  417. +            Area=.630 Path=3.84)
  418.  
  419. *** Ferroxcube toroid cores: 3C8 material
  420.  
  421. .model K502T300_3C8    Core(Ms=420E3 Alpha=2E-5 A=26 K=18 C=1.05
  422. +            Area=.371 Path=7.32)
  423.  
  424. *-------------------------------------------------------------------------------
  425. * Library of MOSFET model parameters (for "power" MOSFET devices)
  426. *
  427. * This is a reduced version of MicroSim's power MOSFET model library.
  428. *   You are welcome to make as many copies of it as you find convenient.
  429. *
  430. * The parameters in this model library were derived from the data sheets for
  431. * each part.  Each part was characterize using the Parts option.
  432. * Device can also be characterized without Parts as follows:
  433. *    LEVEL        Set to 3 (short-channel device).
  434. *    TOX        Determined from gate ratings.
  435. *    L, LD, W, WD    Assume L=2u.  Calculate from input capacitance.
  436. *    XJ, NSUB    Assume usual technology.
  437. *    IS, RD, RB    Determined from "source-drain diode forward voltage"
  438. *            specification or curve (Idr vs. Vsd).
  439. *    RS        Determine from Rds(on) specification.
  440. *    RDS        Calculated from Idss specification or curves.
  441. *    VTO, UO, THETA    Determined from "output characteristics" curve family
  442. *            (Ids vs. Vds, stepped Vgs).
  443. *    ETA, VMAX, CBS    Set for null effect.
  444. *    CBD, PB, MJ    Determined from "capacitance vs. Vds" curves.
  445. *    RG        Calculate from rise/fall time specification or curves.
  446. *    CGSO, CGDO    Determined from gate-charge, turn-on/off delay and
  447. *            rise time specifications.
  448. *
  449. * NOTE:    when specifying the instance of a device in your circuit file:
  450. *
  451. *    BE SURE to have the source and bulk nodes connected together, as this
  452. *    is the way the real device is constructed.
  453. *
  454. *    DO NOT include values for L, W, AD, AS, PD, PS, NRD, or NDS.
  455. *    The PSpice default values for these parameters are taken into account
  456. *    in the library model statements.  Of course, you should NOT reset
  457. *    the default values using the .OPTIONS statement, either.
  458. *
  459. * Example use:    M17    15 23 7 7    IRF150
  460. *
  461. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  462. *
  463. * The "power" MOSFET device models benefit from relatively complete specifi-
  464. * cation of static and dynamic characteristics by their manufacturers.  The
  465. * following effects are modeled:
  466. *    - DC transfer curves in forward operation,
  467. *    - gate drive characteristics and switching delay,
  468. *    - "on" resistance,
  469. *    - reverse-mode "body-diode" operation.
  470. *
  471. * The factors not modeled include:
  472. *    - maximum ratings (eg. high-voltage breakdown),
  473. *    - safe operating area (eg. power dissipation),
  474. *    - latch-up,
  475. *    - noise.
  476. *
  477. * For high-current switching applications, we advise that you include
  478. * series inductance elements, for the source and drain, in your circuit file.
  479. * In doing so, voltage spikes due to di/dt will be modeled.  According to the
  480. * 1985 International Rectifier databook, the following case styles have lead
  481. * inductance values of:
  482. *    TO-204 (modified TO-3)    source = 12.5nH        drain = 5.0nH
  483. *    TO-220            source =  7.5nH        drain = 3.5-4.5nH
  484. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  485. *
  486. .model IRF150    NMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
  487. +        Tox=100n Uo=600 Phi=.6 Rs=1.624m Kp=20.53u W=.3 L=2u Vto=2.831
  488. +            Rd=1.031m Rds=444.4K Cbd=3.229n Pb=.8 Mj=.5 Fc=.5 Cgso=9.027n
  489. +        Cgdo=1.679n Rg=13.89 Is=194E-18 N=1 Tt=288n)
  490. *        Int'l Rectifier    pid=IRFC150    case=TO3
  491. *        88-08-25 bam    creation
  492.  
  493. .model IRF9140    PMOS(Level=3 Gamma=0 Delta=0 Eta=0 Theta=0 Kappa=0 Vmax=0 Xj=0
  494. +        Tox=100n Uo=300 Phi=.6 Rs=70.6m Kp=10.15u W=1.9 L=2u Vto=-3.67
  495. +        Rd=60.66m Rds=444.4K Cbd=2.141n Pb=.8 Mj=.5 Fc=.5 Cgso=877.2p
  496. +        Cgdo=369.3p Rg=.811 Is=52.23E-18 N=2 Tt=140n)
  497. *        Int'l Rectifier  pid=IRFC9140    case=TO3
  498. *        88-08-25 bam    creation
  499.  
  500. *-------------------------------------------------------------------------------
  501. * Library of digital logic
  502.  
  503. * Copyright 1990 by MicroSim Corporation
  504. * This is a reduced version of MicroSim's Digital components library.
  505. *   You are welcome to make as many copies of it as you find convenient.
  506. *
  507. * The parameters in this model library were derived from:
  508. *
  509. *   The TTL Data Book, Texas Instruments, 1985
  510. *     vol. 2
  511. *   ALS/AS Logic Data Book, Texas Instruments, 1986
  512. *     
  513. *   High-speed CMOS Logic Data Book, Texas Instruments, 1988
  514. *     
  515. *   F Logic Data Book, Texas Instruments, 1987
  516. *
  517. *   FAST Data Book, Fairchild, 1982
  518. *
  519. * Each device is modeled by a subcircuit.  The interface pins of the 
  520. * subcircuit have the same name as the pin labels in the data book.  The
  521. * general order is inputs followed by outputs, but on the more complex
  522. * devices you will have to look at the subcircuit definition.
  523. * The word "BAR" is appended to inverted inputs or outputs.
  524. *
  525. * The timing charactistics from the data book are included in the models, 
  526. * with all data sheet effects modeled, unless noted in this file.
  527. *
  528. * If a device contains multiple, independant, identical functions, only 
  529. * one is contained in the subcircuit. (e.g. the 7400 contains four two-
  530. * input NAND gates, but there is only one in the 7400 subckt.)
  531. *
  532. * The subcircuit name is the part name.  Only the 74 series (not the 54
  533. * series) is included in the library, except for a few parts which
  534. * are only made in the 54 series. (e.g. 54L00)
  535. *--------------------------------------------------------------------
  536. *
  537. * TYPES-02: QUADRUPLE 2-INPUT POSITIVE-NOR GATES.
  538. *
  539. .SUBCKT 7402 A B Y
  540. U1 NOR(2) A B Y D_02STD IO_STD
  541. .ENDS
  542. .MODEL D_02STD UGATE
  543. +    (tplhty=12ns    tplhmx=22ns    tphlty=8ns    tphlmx=15ns)
  544. .MODEL IO_STD UIO ( 
  545. +       drvh=96.4, drvl=104, AtoD=AtoD_STD,    DtoA=DtoA_STD)
  546. .MODEL IO_DFT UIO ( 
  547. +       drvh=50, drvl=50, AtoD=AtoD_STD,    DtoA=DtoA_STD )
  548. .SUBCKT AtoDDEFAULT A D
  549. O1 A $G_DGND DO74 DGTLNET = D  IO_DFT
  550. .ENDS
  551.  
  552. .SUBCKT DtoADEFAULT D A
  553. N1 A $G_DGND $G_DPWR DIN74 DGTLNET = D  IO_DFT
  554. .ENDS
  555.  
  556. .model DO74 doutput(
  557. +    s0name = 0, s0vlo = -1.5, s0vhi = 0.8,
  558. +       s1name = X, s1vlo =  0.8, s1vhi = 2.0,
  559. +    s2name = 1, s2vlo =  2.0, s2vhi = 7.0)
  560. .model DIN74 dinput(
  561. +    s0name = 0, s0tsw = 3.5ns, s0rlo = 7.13 s0rhi = 389,  ; 7ohm,    0.09v
  562. +    s1name = 1, s1tsw = 5.5ns, s1rlo = 467  s1rhi = 200,  ; 140ohm,  3.5v
  563. +    s2name = X, s2tsw = 3.5ns, s2rlo = 42.9 s2rhi = 116,  ; 31.3ohm, 1.35v
  564. +    s3name = Z, s3tsw = 3.5ns, s3rlo = 200K s3rhi = 200K)
  565. * - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
  566. * The digital power supply subckt:
  567. *  one instance of this subcircuit is created if any AtoD or DtoA
  568. *  subckts are created.  The one interface pin is always given the 
  569. *  value "0".
  570. *
  571. *  To change the power supply voltage, change the value of VDPWR.
  572. *  To change the digital ground, change the value of VDGND.
  573. *  All interfaces use the global nodes $G_DPWR and $G_DGND as power and 
  574. *  ground.
  575. *
  576. *  The default is that digital ground is 0v, and digital power is 5.0v.
  577.  
  578. .SUBCKT DIGIFPWR GND
  579. VDPWR   $G_DPWR $G_DGND 5v
  580. R1      $G_DPWR GND   1MEG
  581. VDGND   $G_DGND GND   0v
  582. R2      $G_DGND GND   1MEG
  583. .ENDS
  584. * 7400 standard inputs
  585. *
  586. * simple model
  587. *
  588. * connections:       analog input   digital
  589. *                    |              |
  590. .subckt AtoD_STD     a              d
  591. *
  592. O0    a    $G_DGND    DO74  DGTLNET = d  IO_STD
  593. .ends
  594. *
  595. * 7400 standard DtoA model:
  596. *
  597. .SUBCKT DtoA_STD D A
  598. N1 A $G_DGND $G_DPWR DIN74 DGTLNET = D  IO_STD
  599. .ENDS
  600. .MODEL D0_GATE UGATE ()
  601. *
  602. *    Stimulus I/O model
  603.  
  604. .MODEL IO_STM UIO ( 
  605. +       drvh=0, drvl=0, DtoA=DtoA_STM )
  606. *
  607. * Stimulus DtoA model:
  608. *
  609. .SUBCKT DtoA_STM D A
  610. N1 A $G_DGND $G_DPWR DINSTM DGTLNET = D  IO_STM
  611. .ENDS
  612. *----------
  613. *
  614. * TYPES-04: HEX INVERTERS.
  615. *
  616. .SUBCKT 7404 A Y
  617. U1 INV A Y D_04STD IO_STD
  618. .ENDS
  619. .MODEL D_04STD UGATE
  620. +    (tplhty=12ns    tplhmx=22ns    tphlty=8ns    tphlmx=15ns)
  621. *----------
  622. *
  623. * DUAL D-TYPE POSITIVE-EDGE-TRIGGERED FLIP-FLOPS WITH PRESET AND CLEAR
  624. *
  625. .SUBCKT 7474 1CLRBAR 1D 1CLK 1PREBAR 1Q 1QBAR
  626. UFF010 DFF(1) 1PREBAR 1CLRBAR 1CLK 1D 1Q 1QBAR D_74STD_1 IO_STD
  627. .ENDS
  628. .MODEL D_74STD_1 UEFF (TWPCLMN=30NS    TWCLKLMN=37NS    TWCLKHMN=30NS
  629. +    TSUDCLKMN=20NS
  630. +    THDCLKMN=5NS
  631. +    TPPCQLHMX=25NS
  632. +    TPPCQHLMX=40NS
  633. +    TPCLKQLHTY=14NS    TPCLKQLHMX=25NS
  634. +    TPCLKQHLTY=20NS    TPCLKQHLMX=40NS)
  635. *------------------------------------------------------------------
  636. *
  637. * TYPES-393: DUAL 4-BIT BINARY COUNTER WITH INDIVIDUAL CLOCKS.
  638. *
  639.  
  640. .SUBCKT 74393 A CLR QA QB QC QD
  641. U1 JKFF (1) $D_HI CLRB A $D_HI $D_HI QA $D_HI D_393STD_1 IO_STD
  642. U2 JKFF (1) $D_HI CLRB QA $D_HI $D_HI QB $D_HI D_393STD_2 IO_STD
  643. U3 JKFF (1) $D_HI CLRB QB $D_HI $D_HI QC $D_HI D_393STD_2 IO_STD
  644. U4 JKFF (1) $D_HI CLRB QC $D_HI $D_HI QD $D_HI D_393STD_3 IO_STD
  645. U5 INV CLR CLRB D0_GATE IO_STD
  646. .ENDS
  647.  
  648. .MODEL D_393STD_1 UEFF
  649. +    (tppcqhlty=24n tppcqhlmx=39n
  650. +     tpclkqlhty=12n tpclkqlhmx=20n
  651. +     tpclkqhlty=13n tpclkqhlmx=20n
  652. +     twclkhmx=20n twclkhty=20n
  653. +     twclklmx=20n twclklty=20n
  654. +     twpclmx=20n twpclty=20n
  655. +     tsudclkmx=25n tsudclkty=25n)
  656. .MODEL D_393STD_2 UEFF
  657. .MODEL D_393STD_3 UEFF
  658. +    (tpclkqlhty=27n tpclkqlhmx=40n
  659. +     tpclkqhlty=27n tpclkqhlmx=40n)
  660.  
  661. *-------------------------------------------------------------------------------
  662. * Library of optocoupler models
  663.  
  664. * Copyright 1990 by MicroSim Corporation
  665. * This is a reduced version of MicroSim's Opto-coupler components library.
  666. *   You are welcome to make as many copies of it as you find convenient.
  667.  
  668. * The parameters in this model library were derived from the data sheets for
  669. * each part.
  670.  
  671. *.model 4N25
  672. * 6-pin DIP: pin #1   #2   #4   #5   #6
  673. *                |    |    |    |    |
  674. .subckt A4N25      pin1 pin2 pin4 pin5 pin6    params: rel_CTR=1
  675. *        Motorola    pid=4N25
  676. *        88-01-04 pwt
  677. *        88-01-18 pwt    rework Cje approximation
  678.  
  679. * The data sheet used for this model is from Motorola: it was the most
  680. * complete for DC and switching parameters, and is was easy to find the
  681. * component IR-LED and phototransistor as separate devices for further
  682. * specifications.
  683.  
  684.   d_MainLED    pin1 pin2    MainLED
  685.   d_PhotoLED    pin1 1        PhotoLED .001
  686.   v_PhotoLED    1 pin2        0
  687.  
  688.   f_TempComp    0 2        v_PhotoLED 1
  689.   r_TempComp    2 0        TempComp {rel_CTR}
  690.  
  691.   g_BaseSrc    5 6 2 0        .9
  692.   q_PhotoBJT    5 6 4        PhotoBJT
  693.   r_C        5 pin5        .1
  694.   r_B        6 pin6        .1
  695.   r_E        4 pin4        .1
  696.  
  697. * Since active devices dominate pin-to-pin capacitance on each "side" of the
  698. * optocoupler, isolation is modeled by identical capacitances and resistances
  699. * linked to a common point; this gives isolation of .5pF and 1E+11 ohms
  700.   c_1        pin1 7        .4p
  701.   r_1        pin1 7        .12T
  702.   c_2        pin2 7        .4p
  703.   r_2        pin2 7        .12T
  704.   c_4        pin4 7        .4p
  705.   r_4        pin4 7        .12T
  706.   c_5        pin5 7        .4p
  707.   r_5        pin5 7        .12T
  708.   c_6        pin6 7        .4p
  709.   r_6        pin6 7        .12T
  710.  
  711. * Similar to Motorola MLED15.
  712. .model MainLED  D(Is=1.1p Rs=.66 Ikf=30m N=1.9 Xti=3 Cjo=40p M=.34 Vj=.75
  713. +        Isr=30n Nr=3.8 Bv=6 Ibv=100u Tt=.5u)
  714.  
  715. * Models photon generation: same as MainLED except no AC effects, no breakdown.
  716. .model PhotoLED D(Is=1.1p Rs=.66 Ikf=30m N=1.9 Xti=3 Cjo=0   M=.34 Vj=.75
  717. +        Isr=30n Nr=3.8 Bv=0 Tt=0)
  718.  
  719. * Temperature compensation for system: 1.38x @ -55'C, .54x @ +100'C, all @ 10mA
  720. * Note: the photo BJT has its own temperature corrections, which must be kept
  721. * as the transistor is electrically available.
  722. .model TempComp    RES(R=1 Tc1=-11.27m Tc2=43.46u)
  723.  
  724. * Similar to Motorola MDR3050; Hfe=325 @ Ic=500uA, Vce=5V
  725. * Use beta variation (w/Parts) to model change in current-transfer ratio (CTR).
  726. * Hand adjust reverse beta (Br) to match saturation characteristics.
  727. * Set Isc to model dark current.
  728. * Hand adjust Cjc to match fall time @ Ic=10mA (which yields rise time, too).
  729. * Hand adjust reverse transit-time (Tr) to match storage time @ Ic=10mA.
  730. * Delay time set by LED I-V and C-V characteristics; set Cje to 25% of Cjc,
  731. * inspection of phototransistor chip layouts show the emitter area is 20%-25%
  732. * that of the collector area.  The same layouts show that base resistance is
  733. * made negligible by design; also, the operating currents are small.
  734. * Hand adjust forward transit-time (Tf) to match MDR3050 pulse data.  Check
  735. * against 4N25 frequency response (Fig 11, 12).
  736. .model PhotoBJT NPN(Is=10f Xti=3 Vaf=60
  737. +        Bf=400 Ne=3.75 Ise=580p Ikf=.26 Xtb=1.5
  738. +        Br=.04 Nc=2    Isc=3.5n
  739. +        Cjc=10p  Mjc=.3333 Vjc=.75 Tr=88u
  740. +        Cje=2.5p Mje=.3333 Vje=.75 Tf=1.5n)
  741. .ends
  742.  
  743. *.model 4N25A
  744. * 6-pin DIP: pin #1   #2   #4   #5   #6
  745. *                |    |    |    |    |
  746. .subckt A4N25A    pin1 pin2 pin4 pin5 pin6
  747. *        88-01-05 pwt
  748. * Same as 4N25 (UL recognized).
  749.   x1 pin1 pin2 pin4 pin5 pin6 A4N25
  750. .ends
  751.  
  752. *-------------------------------------------------------------------------------
  753. * Library of Thyristor (SCR and Triac) models
  754.  
  755. * Copyright 1990 by MicroSim Corporation
  756. * This is a reduced version of MicroSim's Thyristor components library.
  757. *   You are welcome to make as many copies of it as you find convenient.
  758.  
  759. * $Revision:   1.6  $
  760. * $Author:   gwb  $
  761. * $Date:   15 Jun 1990 14:21:38  $
  762.  
  763. * Library of SCR models
  764.  
  765. * NOTE:  This library requires the "Analog Behavioral Modeling"
  766. *        option available with PSpice.  A model developed without
  767. *        Behavioral Modeling was found to be very slow and not
  768. *        very robust.
  769.  
  770. * This macromodel uses a controlled switch as the basic SCR
  771. * structure.  In all cases, the designer should use
  772. * the manufacturer's data book for actual part selection.
  773.  
  774. * The required parameters were derived from data sheet (Motorola)
  775. * information on each part.  When available, only "typical"
  776. * parameters are used (except for Idrm which is always
  777. * a "max" value).  If a "typical" parameter is not available,
  778. * a "min" or "max" value may be used in which case a comment is
  779. * made in the library.  
  780.  
  781. * The SCRs are modeled at room temperature and do not track
  782. * changes with temperature.  Note that Vdrm is specified by the
  783. * manufacturer as valid over a temperature range.  Also, in
  784. * nearly all cases, dVdt and Toff are specified by the
  785. * manufacturer at approximately 100 degrees C.  This results in a
  786. * model which is somewhat "conservative" for a room temperature
  787. * model.
  788.  
  789. * The parameter dVdt (when available from the date sheet) is used
  790. * to model the Critical Rate of Rise of Off-State Voltage.  If
  791. * not specified, dVdt is defaulted to 1000 V/microsecond.
  792. * A side effect of this model is that the turn-on current, Ion,
  793. * is determined by Vtm/(Ih*Vdrm).  Vtm is also used as the
  794. * holding voltage.
  795.  
  796. .SUBCKT Scr anode gate cathode PARAMS:
  797. + Vdrm=400v     Vrrm=400v     Idrm=10u
  798. + Ih=6ma        dVdt=5e7
  799. + Igt=5ma       Vgt=0.7v
  800. + Vtm=1.7v      Itm=24
  801. + Ton=1u        Toff=15u
  802.  
  803. * Where:
  804. * Vdrm =>  Forward breakover voltage
  805. * Vrrm =>  Reverse breakdown voltage
  806. * Idrm =>  Peak blocking current
  807. * Ih   =>  Holding current
  808. * dVdt =>  Critical value for dV/dt triggering
  809. * Igt  =>  Gate trigger current
  810. * Vgt  =>  Gate trigger voltage
  811. * Vtm  =>  On-state voltage
  812. * Itm  =>  On-state current
  813. * Ton  =>  Turn-on time
  814. * Toff =>  Turn-off time
  815.  
  816. * Main conduction path
  817. Scr      anode   anode0  control 0       Vswitch ; controlled switch
  818. Dak1     anode0  anode2  Dakfwd  OFF             ; SCR is initially off
  819. Dka      cathode anode0  Dkarev  OFF
  820. VIak     anode2  cathode                         ; current sensor
  821.  
  822. * dVdt Turn-on
  823. Emon     dvdt0   0       TABLE {v(anode,cathode)} (0 0) (2000 2000)
  824. CdVdt    dvdt0   dvdt1   100pfd                  ; displacement current
  825. Rdlay    dvdt1   dvdt2   1k
  826. VdVdt    dvdt2   cathode DC 0.0
  827. EdVdt    condvdt 0       TABLE {i(vdVdt)-100p*dVdt}  (0 0 ) (.1m 10)
  828. RdVdt    condvdt 0       1meg
  829.  
  830. * Gate
  831. Rseries  gate    gate1   {(Vgt-0.65)/Igt}
  832. Rshunt   gate1   gate2   {0.65/Igt}
  833. Dgkf     gate1   gate2   Dgk
  834. VIgf     gate2   cathode                         ; current sensor
  835.  
  836. * Gate Turn-on
  837. Egate1   gate4   0       TABLE {i(Vigf)-0.95*Igt} (0 0) (1m 10)
  838. Rgate1   gate4   0       1meg
  839. Egon1    congate 0       TABLE {v(gate4)*v(anode,cathode)} (0 0) (10 10)
  840. Rgon1    congate 0       1meg
  841.  
  842. * Main Turn-on
  843. EItot    Itot    0       TABLE {i(VIak)+5E-5*i(VIgf)/Igt} (0 0) (2000 2000)
  844. RItot    Itot    0       1meg
  845. Eprod    prod    0       TABLE {v(anode,cathode)*v(Itot)} (0 0) (1 1)
  846. Rprod    prod    0       1meg
  847. Elin     conmain 0       TABLE
  848. +        {10*(v(prod) - (Vtm*Ih))/(Vtm*Ih)} (0 0) (2 10)
  849. Rlin     conmain 0       1meg
  850.  
  851. * Turn-on/Turn-off control
  852. Eonoff   contot  0       TABLE
  853. +        {v(congate)+v(conmain)+v(condvdt)} (0 0) (10 10)
  854.  
  855. * Turn-on/Turn-off delays
  856. Rton    contot  dlay1   825
  857. Dton    dlay1   control Delay
  858. Rtoff   contot  dlay2   {290*Toff/Ton}
  859. Dtoff   control dlay2   Delay
  860. Cton    control 0       {Ton/454}
  861.  
  862. * Reverse breakdown
  863. Dbreak  anode   break1  Dbreak
  864. Dbreak2 cathode break1  Dseries
  865.  
  866. * Controlled switch model
  867. .MODEL Vswitch vswitch
  868. + (Ron = {(Vtm-0.7)/Itm}, Roff = {Vdrm*Vdrm/(Vtm*Ih)},
  869. +  Von = 5.0,             Voff = 1.5)
  870.  
  871. * Diodes
  872. .MODEL  Dgk     D       (Is=1E-16 Cjo=50pf Rs=5)
  873. .MODEL  Dseries D       (Is=1E-14)
  874. .MODEL  Delay   D       (Is=1E-12 Cjo=5pf  Rs=0.01)
  875. .MODEL  Dkarev  D       (Is=1E-10 Cjo=5pf  Rs=0.01)
  876. .MODEL  Dakfwd  D       (Is=4E-11 Cjo=5pf)
  877. .MODEL  Dbreak  D       (Ibv=1E-7 Bv={1.1*Vrrm} Cjo=5pf Rs=0.5)
  878.  
  879. * Allow the gate to float if required
  880. Rfloat  gate    cathode 1e10
  881.  
  882. .ENDS
  883. *
  884. .SUBCKT 2N1595          anode gate cathode
  885. * "Typical" parameters
  886. X1 anode gate cathode Scr PARAMS:
  887. + Vdrm=50v   Vrrm=50v     Ih=5ma       Vtm=1.1v     Itm=1
  888. + dVdt=1e9   Igt=2ma      Vgt=.7v      Ton=0.8u     Toff=10u
  889. + Idrm=10u
  890. * 90-5-18    Morotola     DL137, Rev 2, 3/89
  891. .ENDS
  892.  
  893. * Library of Triac models
  894.  
  895. * NOTE:  This library requires the "Analog Behavioral Modeling"
  896. *        option available with PSpice.
  897.  
  898. * This macromodel uses two controlled switches as the basic triac
  899. * structure.  The model was developed to provide firing in all
  900. * four quadrants.  It should be noted, however, that the library
  901. * contains parts which the manufacturer has guaranteed will fire
  902. * in 4 quadrants, 3 quadrants or 2 quadrants.  Therefore, the
  903. * designer should always use the manufacturer's data book for
  904. * part selection.
  905.  
  906. * The required parameters were derived from data sheet (Motorola)
  907. * information on each part.  When available, only "typical"
  908. * parameters are used (except for Idrm which is always
  909. * a "max" value).  If a "typical" parameter is not available,
  910. * a "min" or "max" value may be used in which case a comment is
  911. * made in the library.  
  912.  
  913. * The triacs are modeled at room temperature and do not track
  914. * changes with temperature.  Note that Vdrm is specified by the
  915. * manufacturer as valid over a temperature range.  Also, in
  916. * nearly all cases, dVdt is specified by the manufacturer at
  917. * approximately 100 degrees C.  This results in a model which
  918. * is somewhat "conservative" for a room temperature model.
  919.  
  920. * The parameter dVdt (when available from the date sheet) is used
  921. * to model the Critical Rate of Rise of Off-State Voltage.  If
  922. * not specified, dVdt is defaulted to 1000 V/microsecond.  The
  923. * Critical Rate of Rise of Commutation Voltage is not modeled.
  924. * It is generally good practice to use an RC snubber network
  925. * across the triac to limit the commutating dvdt to a value below
  926. * the maximum allowable rating (see manufacturer's data sheet and
  927. * application notes).  Also, note that the turn-off time is
  928. * assumed to be zero.
  929.  
  930. .SUBCKT Triac MT2 gate MT1 PARAMS:
  931. + Vdrm=400v     Idrm=10u
  932. + Ih=6ma        dVdt=50e6
  933. + Igt=20ma      Vgt=0.9v
  934. + Vtm=1.3v      Itm=17
  935. + Ton=1.5u
  936.  
  937. * Where:
  938. * Vdrm =>  Forward breakover voltage
  939. * Idrm =>  Peak blocking current
  940. * Ih   =>  Holding current [MT2(+)]
  941. * dVdt =>  Critical value for dV/dt triggering
  942. * Igt  =>  Gate trigger current [MT2(+),G(-)]
  943. * Vgt  =>  Gate trigger voltage [MT2(+),G(-)]
  944. * Vtm  =>  On-state voltage
  945. * Itm  =>  On-state current
  946. * Ton  =>  Turn-on time
  947.  
  948. * Main conduction path
  949. Striac   MT2     MT20    cntrol   0       Vswitch ; controlled switch
  950. Dak1     MT20    MT22    Dak      OFF             ; triac is initially off
  951. VIak     MT22    MT1                              ; current sensor
  952. Striacr  MT2     MT23    cntrolr  0       Vswitch ; controlled switch
  953. Dka1     MT21    MT23    Dak      OFF             ; triac is initially off
  954. VIka     MT1     MT21                             ; reverse current sense
  955.  
  956. * dVdt Turn-on
  957. Emon     dvdt0   0       TABLE {ABS(V(MT2,MT1))} (0 0) (2000 2000)
  958. CdVdt    dvdt0   dvdt1   100pfd                  ; displacement current
  959. Rdlay    dvdt1   dvdt2   1k
  960. VdVdt    dvdt2   MT1     DC 0.0
  961. EdVdt    condvdt 0       TABLE {i(vdVdt)-100p*dVdt}  (0 0 ) (.1m 10)
  962. RdVdt    condvdt 0       1meg
  963.  
  964. * Gate
  965. Rseries  gate    gate1   {(Vgt-0.65)/Igt}
  966. Rshunt   gate1   gate2   {0.65/Igt}
  967. Dgkf     gate1   gate2   Dgk
  968. Dgkr     gate2   gate1   Dgk
  969. VIgf     gate2   MT1     DC 0.0                  ; current sensor
  970.  
  971. * Gate Turn-on
  972. Egate    congate 0       TABLE {(ABS(i(VIgf))-0.95*Igt)} (0 0) (1m 10)
  973. Rgate    congate 0       1meg
  974.  
  975. * Holding current, holding voltage (Quadrant I)
  976. Emain1   main1   0       TABLE {i(VIak)-Ih+5e-3*i(VIgf)/Igt} (0 0) (.1m 1)
  977. Rmain1   main1   0       1meg
  978. Emain2   main2   0       TABLE {v(MT2,MT1)-(Ih*Vtm/Itm)} (0 0) (.1m 1)
  979. Rmain2   main2   0       1meg
  980. Emain3   cnhold  0       TABLE {v(main1,0)*v(main2,0)} (0 0 (1 10)
  981. Rmain3   cnhold  0       1meg
  982.  
  983. * Holding current, holding voltage (Quadrant III)
  984. Emain1r  main1r   0       TABLE {i(VIka)-Ih-5e-3*i(VIgf)/Igt} (0 0) (.1m 1)
  985. Rmain1r  main1r   0       1meg
  986. Emain2r  main2r   0       TABLE {v(MT1,MT2)-(Ih*Vtm/Itm)} (0 0) (.1m 1)
  987. Rmain2r  main2r   0       1meg
  988. Emain3r  cnholdr  0       TABLE {v(main1r,0)*v(main2r,0)} (0 0 (1 10)
  989. Rmain3r  cnholdr  0       1meg
  990.  
  991. * Main
  992. Emain4   main4    0       table {(1.0-ABS(i(VIgf))/Igt)} (0 0) (1 1)
  993. Rmain4   main4    0       1meg
  994. Emain5   cnmain   0       table {v(mt2,mt1)-1.05*Vdrm*v(main4)} (0 0) (1 10)
  995. Rmain5   cnmain   0       1meg
  996.  
  997. Emain5r  cnmainr  0       table {v(mt1,mt2)-1.05*Vdrm*v(main4)} (0 0) (1 10)
  998. Rmain5r  cnmainr  0       1meg
  999.  
  1000. * Turn-on/Turn-off control (Quadrant I )
  1001. Eonoff   contot  0       TABLE
  1002. +        {v(cnmain)+v(congate)+v(cnhold)+v(condvdt)} (0 0) (10 10)
  1003.  
  1004. * Turn-on/Turn-off delays (Quadrant I)
  1005. Rton     contot  dlay1   825
  1006. Dton     dlay1   cntrol  Delay
  1007. Rtoff    contot  dlay2   {2.9E-3/Ton}
  1008. Dtoff    cntrol  dlay2   Delay
  1009. Cton     cntrol  0       {Ton/454}
  1010.  
  1011. * Turn-on/Turn-off control (Quadrant III)
  1012. Eonoffr  contotr 0       TABLE
  1013. +        {v(cnmainr)+v(congate)+v(cnholdr)+v(condvdt)} (0 0) (10 10)
  1014.  
  1015. * Turn-on/Turn-off delays (Quadrant III)
  1016. Rtonr    contotr dlayr1   825
  1017. Dtonr    dlayr1  cntrolr  Delay
  1018. Rtoffr   contotr dlayr2   {2.9E-3/Ton}
  1019. Dtoffr   cntrolr dlayr2   Delay
  1020. Ctonr    cntrolr 0        {Ton/454}
  1021.  
  1022. * Controlled switch model
  1023. .MODEL Vswitch vswitch
  1024. + (Ron = {(Vtm-0.7)/Itm}, Roff = {1.75E-3*Vdrm/Idrm},
  1025. +  Von = 5.0,             Voff = 1.5)
  1026.  
  1027. * Diodes
  1028. .MODEL  Dgk     D         (Is=1E-16 Cjo=50pf Rs=5)
  1029. .MODEL  Delay   D         (Is=1E-12 Cjo=5pf  Rs=0.01)
  1030. .MODEL  Dak     D         (Is=4E-11 Cjo=5pf)
  1031.  
  1032. * Allow the gate to float if required
  1033. Rfloat  gate    MT1 1e10
  1034.  
  1035. .ENDS
  1036. *
  1037. .SUBCKT 2N5444          MT2 gate MT1
  1038. * Min and Max parameters
  1039. X1 MT2 gate MT1 Triac PARAMS:
  1040. + Vdrm=200v  Idrm=10u     Ih=70ma      dVdt=50e6   Ton=1u
  1041. + Igt=70ma   Vgt=2.0v     Vtm=1.65v    Itm=56
  1042. * 90-5-18    Morotola     DL137, Rev 2, 3/89
  1043. .ENDS
  1044.  
  1045. * End of library file
  1046.  
  1047.